#ifndef MyAppVersion
  #define MyAppVersion "1.0.0"
#endif

#ifndef StageDir
  #define StageDir "..\..\release\windows-app"
#endif

#ifndef OutputDir
  #define OutputDir "..\..\release\windows-installer"
#endif

#ifndef IconFile
  #define IconFile "assets\ssh-manager.ico"
#endif

#define MyAppName "SSH Manager"
#define MyAppPublisher "SSH Manager"
#define MyAppURL "http://127.0.0.1:48080"

[Setup]
AppId={{7EFC73C3-79F8-4CC2-92A1-8C3A56E4E8B1}
AppName={#MyAppName}
AppVerName={#MyAppName} {#MyAppVersion}
AppVersion={#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
UninstallDisplayName={#MyAppName}
UninstallDisplayIcon={app}\ssh-manager.ico
SetupIconFile={#IconFile}
DefaultDirName={autopf}\SSH Manager
DefaultGroupName=SSH Manager
ArchitecturesInstallIn64BitMode=x64compatible
PrivilegesRequired=admin
AppMutex=SSHManagerLocalApp
Compression=lzma
SolidCompression=yes
WizardStyle=modern
SetupLogging=yes
OutputDir={#OutputDir}
OutputBaseFilename=SSHManager-Setup-{#MyAppVersion}
VersionInfoVersion={#MyAppVersion}
VersionInfoCompany={#MyAppPublisher}
VersionInfoDescription=SSH Manager Windows 本地管理工具
VersionInfoProductName={#MyAppName}
VersionInfoProductVersion={#MyAppVersion}
VersionInfoCopyright=SSH Manager

[Languages]
Name: "chinesesimp"; MessagesFile: "compiler:Languages\ChineseSimplified.isl"

[Tasks]
Name: "desktopicon"; Description: "创建桌面快捷方式"; GroupDescription: "附加任务:"; Flags: unchecked

[Files]
Source: "{#StageDir}\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs

[Icons]
Name: "{group}\SSH Manager"; Filename: "{app}\start-installed.vbs"; WorkingDir: "{app}"; IconFilename: "{app}\ssh-manager.ico"
Name: "{group}\停止 SSH Manager"; Filename: "{app}\stop-installed.cmd"; WorkingDir: "{app}"; IconFilename: "{app}\ssh-manager.ico"
Name: "{group}\买家使用说明"; Filename: "{app}\BUYER-GUIDE.txt"; WorkingDir: "{app}"; IconFilename: "{app}\ssh-manager.ico"
Name: "{group}\售后排查 FAQ"; Filename: "{app}\AFTER-SALES-FAQ.txt"; WorkingDir: "{app}"; IconFilename: "{app}\ssh-manager.ico"
Name: "{group}\打开安装目录"; Filename: "{app}"
Name: "{autodesktop}\SSH Manager"; Filename: "{app}\start-installed.vbs"; WorkingDir: "{app}"; Tasks: desktopicon; IconFilename: "{app}\ssh-manager.ico"

[Run]
Filename: "{app}\start-installed.vbs"; Description: "立即启动 SSH Manager"; Flags: nowait postinstall skipifsilent

[UninstallDelete]
Type: files; Name: "{localappdata}\SSHManager\runtime\app.pid"